TEMPDIR := `mktemp -d`
BUILDDIR := "_build"
alias dr := debug-run
alias dt := debug-test


docker:
    docker build -t go-git-server .

docker-run:
    docker run -it --rm -p 8080:8080 --volume $(pwd)/tokens.csv:/opt/app/etc/tokens.csv go-git-server

clean:
    rm -r {{ BUILDDIR }}

builddir:
    mkdir -p {{ BUILDDIR }}/etc
    mkdir -p {{ BUILDDIR }}/bin

build: test builddir
    cp policy.csv auth_model.ini gitserver.yaml {{ BUILDDIR }}/etc/ 
    CGO_ENABLED=0 go build -a -ldflags '-s' -o {{ BUILDDIR }}//bin/go-git-server cmd/main.go

push: docker
    docker tag go-git-server:latest public.ecr.aws/s0f9o2k5/go-git-server:latest 
    docker push public.ecr.aws/s0f9o2k5/go-git-server:latest

run:
    go run cmd/main.go -s {{justfile_directory()}}/gitserver.yaml -r $(mktemp -d)

test:
    golangci-lint run
    go test -v -coverprofile={{ TEMPDIR }}/testcover.out ./...
    go tool cover -func={{ TEMPDIR }}/testcover.out

debug-run:
    dlv debug cmd/main.go -- -s {{justfile_directory()}}/gitserver.yaml -r $(mktemp -d) 

debug-test pkg:
    dlv test {{pkg}} -- -test.v